摘要：集成了乘累加單元(MAC)和單周期內(nèi)核的MAXQ2000非常適合用作通用微控制器(μC) 。MAXQ2000所具有的性能和I/O外設(shè)適合多種應(yīng)用：如鬧鐘、手持醫(yī)療設(shè)備、數(shù)字讀取器等需要低功耗、高性能和大量I/O的應(yīng)用。集成MAC的MAXQ2000已可以進(jìn)入DSP (μC)的應(yīng)用領(lǐng)域。

MAXQ2000的MAC能夠發(fā)揮多大的性能?本應(yīng)用筆記以一個(gè)音頻濾波器為例來解釋此問題，并定量給出MAXQ2000支持的性能。

軟件和硬件要求

本應(yīng)用筆記簡單演示一個(gè)音頻濾波器。音頻數(shù)據(jù)事先錄制，是由作者朗讀的 "The pipe began to rust while new"。這并不是隨機(jī)選擇的，它含有適當(dāng)?shù)念l率組合，可以檢驗(yàn)濾波器的效果(http://www.cs.columbia.edu/~hgs/audio/harvard.html )。該音頻錄音可以用任意合適長度的8kHz錄音替代，但并不必要。

本應(yīng)用筆記要求的硬件包括MAXQ2000評估板和實(shí)現(xiàn)與計(jì)算機(jī)揚(yáng)聲器接口的簡單電路。

現(xiàn)已提供的MAXQ2000評估板是了解MAXQ2000性能的最佳工具，它包括一塊LCD面板、一組LED?？赏ㄟ^評估板訪問MAXQ2000的所有I/O引腳。評估板集成的MAX1407 ADC/DAC可用于音頻輸出。

所需的第二部分硬件可由電路實(shí)驗(yàn)板方便實(shí)現(xiàn)。演示使用的電路如圖1所示。它使用一個(gè)1 x 8的孔插座在J7處連接MAXQ2000評估板，需要和任意地電位相連(可選擇MAXQ2000評估板上的TP1)。揚(yáng)聲器連接器可以是任意類型，圖中所示為一個(gè)3.5mm立體聲插孔，可方便實(shí)現(xiàn)與常用計(jì)算機(jī)揚(yáng)聲器連接。注意兩輸入通道并聯(lián)，因?yàn)槲覀兊难菔緝H使用一個(gè)音頻通道(單聲道)。


圖1. 音頻回放所需的其它硬件

該演示所需的軟件采用IAR嵌入式平臺創(chuàng)建并調(diào)試。該平臺提供一個(gè)良好的調(diào)試環(huán)境，使用了MAXQ2000的硬件調(diào)試支持?？稍O(shè)置斷點(diǎn)，設(shè)置或讀取寄存器和存儲器，在真實(shí)硬件環(huán)境中運(yùn)行時(shí)可查看堆棧調(diào)用。

運(yùn)行演示

MAXQ2000評估板上的按鍵用于選擇濾波器，并播放經(jīng)過濾波的音頻采樣。使用按鍵SW4選擇濾波器，濾波器名稱將顯示在LCD上(HI為高通、LO為低通、BP為帶通，ALL為全通)。使用按鍵SW5播放通過所選濾波器的音頻?？稍诓シ牌陂g切換濾波器。

設(shè)計(jì)一個(gè)簡單的FIR濾波器

本文使用一個(gè)Java?小應(yīng)用程序來方便的產(chǎn)生新的濾波器。沒有采用標(biāo)準(zhǔn)加窗技術(shù)給出濾波器參數(shù)，而是如圖2所示，在零極點(diǎn)圖上放置零點(diǎn)來簡單“設(shè)計(jì)”濾波器。小應(yīng)用程序可在坐標(biāo)平面任意位置放置零點(diǎn)，自動更新演示所需FIR濾波器的參數(shù)。注意，演示僅支持全零點(diǎn)濾波器。支持IIR濾波器并不困難，在支持IIR濾波器一節(jié)中有詳細(xì)解釋。


圖2. 使用零極點(diǎn)圖來生成一個(gè)簡單的FIR濾波器

普通濾波器的線性方程為：

y(n) + bKy(k) = aJx(j)

其中k表示濾波器反饋部分的階數(shù)，j表示濾波器前饋部分的階數(shù)。

一個(gè)IIR濾波器可由下式簡單表示：

y(n) = 0.5y(n-1) + x(n) - 0.8x(n-1)

一些濾波器被歸類為FIR濾波器，不包括反饋部分。換句話說，在濾波器特征方程中不包括y部分：

y(n) = aJx(j)
y(n) = x(n) - 0.2x(n - 1) + 0.035x(n - 3)

任何情況下濾波器都可歸結(jié)為一個(gè)特征方程，本質(zhì)上是過去的輸入和輸出的加權(quán)平均。濾波器設(shè)計(jì)即生成Aj和Bk值。為高效計(jì)算濾波器輸出，需要能快速乘和加有符號數(shù)硬件的支持，這就是MAXQ2000的乘-累加單元。

使用乘-累加(MAC)單元實(shí)現(xiàn)一個(gè)濾波器

上一節(jié)中的小應(yīng)用程序可通過在圖中指定零點(diǎn)坐標(biāo)計(jì)算濾波器參數(shù)。但計(jì)算結(jié)果為浮點(diǎn)數(shù)，而MAC為純16位整數(shù)運(yùn)算。為解決這一問題，本演示采用了一個(gè)定點(diǎn)數(shù)值系統(tǒng)，參數(shù)的0至15位為小數(shù)點(diǎn)右側(cè)的數(shù)值(第16位代表符號極性)。運(yùn)算完成后，MAC累加器中的48位結(jié)果通過移位去掉剩余部分。

這種解決方法是精度和速度的折衷。在許多情況下，該方法產(chǎn)生的誤差可忽略。出于診斷目的，小應(yīng)用程序可顯示所計(jì)算濾波器的三條曲線。第一條曲線采用64位浮點(diǎn)數(shù)顯示理想濾波器的運(yùn)行狀態(tài)。該曲線在圖2中以“Ideal Transform”標(biāo)示。

圖3畫出了由小應(yīng)用程序產(chǎn)生的其余曲線。其中第一條曲線顯示采用16位定點(diǎn)數(shù)的濾波效果。在許多情況下，誤差并不明顯。最后一條曲線為誤差指示，顯示的是理想頻響除以實(shí)際頻響。理想情況下，這是一條Y = 1的直線。


圖3. 16位濾波器實(shí)際效果和舍入誤差(視覺上沒有誤差)

簡單起見，小應(yīng)用程序產(chǎn)生MAXQ?濾波器所需的浮點(diǎn)參數(shù)，因此，新濾波器可簡單通過將其剪切并粘貼到濾波器源文件(data.asm文件)中實(shí)現(xiàn)。小應(yīng)用程序還產(chǎn)生另外兩個(gè)值，即濾波器階數(shù)(參數(shù)個(gè)數(shù))和移位數(shù)，應(yīng)用程序可適當(dāng)移位最終結(jié)果。數(shù)據(jù)出現(xiàn)在小應(yīng)用程序底部文本框中，可能會以以下方式呈現(xiàn)：

Zeroes:
    dc16
    dc16 12, 11, 0x1000, 0x26d3, 0x1e42, 0xf9a3, 0xecde, 0xff31, 0xa94,
         0x2ae, 0xfd0c, 0xff42, 0xde
Shift amount: 12

用MAXQ匯編語言實(shí)現(xiàn)濾波器

為得到最佳性能，并進(jìn)行準(zhǔn)確的性能分析，實(shí)際濾波器采用匯編語言實(shí)現(xiàn)，這樣可精確計(jì)算產(chǎn)生一個(gè)輸出所需的循環(huán)次數(shù)，并由此估算其它數(shù)據(jù)設(shè)置的性能。

MAX1407含有一個(gè)12位ADC。而輸入數(shù)據(jù)為16位寬度，濾波器產(chǎn)生16位結(jié)果。盡管4個(gè)最低有效位(LSB)在本應(yīng)用中沒有用到，但仍可按16位計(jì)算和輸出正常分析其性能(CD質(zhì)量的音頻為16位)。

本例中，濾波器參數(shù)存儲在代碼區(qū)的表中。選擇一個(gè)濾波器后，應(yīng)用程序找到合適的濾波器，讀取移位數(shù)及抽頭數(shù)，然后準(zhǔn)備開始數(shù)字濾波。以下代碼應(yīng)用了濾波器參數(shù)：

    move  MCNT, #22h           ; signed, mult-accum, clear regs first

zeroes_filterloop:
    move  A[0], DP[0]          ; let's see if we are out of data
    cmp   #W:rawaudiodata      ; compare to the start of the audio data
    lcall UROM_MOVEDP1INC      ; get next filter coefficient
    move  MA, GR               ; multiply filter coefficient...
    lcall UROM_MOVEDP0DEC      ; get next filter data
    move  MB, GR               ; multiply audio sample...
    jump  e, zeroes_outofdata  ; stop if at the start of the audio data
    djnz  LC[0], zeroes_filterloop

zeroes_outofdata:
    move  A[2], MC2            ; get MAC result HIGH
    move  A[1], MC1            ; get MAC result MID
    move  A[0], MC0            ; get MAC result LOW

執(zhí)行該代碼前，LC[0]裝入濾波器抽頭數(shù)，DP[0]裝入濾波器當(dāng)前輸入字節(jié)地址，DP[1]裝入濾波器參數(shù)起始地址。DP[1]以遞增方式處理濾波器參數(shù)，DP[0]以遞減方式處理輸入數(shù)據(jù)(最近輸入的數(shù)據(jù)首先處理)。

由于MAC以單周期工作，處理代碼較少。MCNT置為22h代表采用有符號整數(shù)。在主循環(huán)中，連續(xù)寫入MA，然后寫MB觸發(fā)乘-累加運(yùn)算，結(jié)果在下一個(gè)時(shí)鐘周期準(zhǔn)備就緒。由于累加器為48位(乘的結(jié)果為32位)，因此不會產(chǎn)生溢出(除非濾波器中有64,000個(gè)抽頭！)。

性能

該應(yīng)用處理單聲道16位音頻數(shù)據(jù)并產(chǎn)生8kHz輸出，還沒有完全發(fā)揮微控制器的能力。由于使用匯編語言編寫濾波器，可用一個(gè)表達(dá)式方便算出用于計(jì)算長度為N的FIR濾波器所需的周期數(shù)。然后還可使用該表達(dá)式計(jì)算出采用前面所列算法的最大濾波速率。

可將用于產(chǎn)生音頻采樣的功能分成3部分：初始化、濾波器計(jì)算循環(huán)以及結(jié)果修正。在該例中，初始化需要38個(gè)周期，濾波器計(jì)算中每個(gè)濾波器參數(shù)需要17個(gè)周期，結(jié)果修正需要9 + (6 x S)個(gè)周期，其中S是移位數(shù)。通常，移位數(shù)為12，則結(jié)果修正為81個(gè)周期。因此，需要119 + (17 x N)個(gè)周期產(chǎn)生一個(gè)濾波輸出結(jié)果。20MHz時(shí)，MAXQ2000可以運(yùn)行近11kHz的100抽頭濾波器，這已經(jīng)是相當(dāng)好的語音質(zhì)量。

現(xiàn)在回到前面重新分析應(yīng)用程序以進(jìn)一步進(jìn)行簡化。我們將主要針對濾波器循環(huán)，因?yàn)榇颂幷加昧硕鄶?shù)周期，并且最煩瑣。

還可以對循環(huán)代碼進(jìn)行幾處關(guān)鍵改進(jìn)以提高效率。注意，我們采用了預(yù)先錄制并存儲在代碼區(qū)的音頻采樣。由于MAXQ采用哈佛體系結(jié)構(gòu)，因此查找代碼空間比查找數(shù)據(jù)空間需要更多的時(shí)間。稱為UROM_MOVEDP1INC和UROM_MOVEDP0DEC的函數(shù)每個(gè)執(zhí)行需要5個(gè)周期(LCALL為2周期，函數(shù)內(nèi)部為3周期)。如果濾波器存儲在RAM中并處理存儲在RAM中的實(shí)時(shí)輸入數(shù)據(jù)，則每個(gè)只需兩周期(一個(gè)周期選擇指針，一個(gè)周期讀)。如果將RAM中的256個(gè)字用于濾波器，可用BP[Offs]實(shí)現(xiàn)一個(gè)環(huán)形緩沖區(qū)來存儲輸入數(shù)據(jù)。這些改動可將循環(huán)時(shí)間由17個(gè)周期縮短為11個(gè)。這樣的濾波器循環(huán)為下所示(在注釋中首先列出所需周期數(shù))：

zeroes_filterloop:
    move  A[0], DP[0]          ; 1, let's see if we are out of data
    cmp   #W:rawaudiodata      ; 2, compare to the start of the audio data
    move  DP[1], DP[1]         ; 1, select DP[1] as our active pointer
    move  GR, @DP[1]++         ; 1, get next filter coefficient
    move  MA, GR               ; 1, multiply filter coefficient...
    move  BP, BP               ; 1, select BP[Offs] as our active pointer
    move  GR, @BP[Offs--]      ; 1, get next filter data
    move  MB, GR               ; 1, multiply audio sample...
    jump  e, zeroes_outofdata  ; 1, stop if at the start of the audio data
    djnz  LC[0], zeroes_filterloop  ; 1

將濾波器及輸入數(shù)據(jù)裝入RAM后還可以利用MAXQ體系結(jié)構(gòu)的另一特點(diǎn)。MAXQ指令集高度不相關(guān)，在任何操作中，對采用何種源幾乎沒有限制。因此，可不將濾波器數(shù)據(jù)和輸入數(shù)據(jù)讀入GR，而是直接寫入MAC寄存器。這樣可使循環(huán)降至9個(gè)周期。

zeroes_filterloop:
    move  A[0], DP[0]          ; 1, let's see if we are out of data
    cmp   #W:rawaudiodata      ; 2, compare to the start of the audio data
    move  DP[1], DP[1]         ; 1, select DP[1] as our active pointer
    move  MA, @DP[1]++         ; 1, multiply next filter coefficient
    move  BP, BP               ; 1, select BP[Offs] as our active pointer
    move  MB, @BP[Offs--]      ; 1, multiply next filter data
    jump  e, zeroes_outofdata  ; 1, stop if at the start of the audio data
    djnz  LC[0], zeroes_filterloop  ; 1

最后的修改可極大改進(jìn)該代碼。每次循環(huán)時(shí)，比較當(dāng)前數(shù)據(jù)指針和音頻輸入數(shù)據(jù)起始位置，以查看是否越界(MOVE A[0], DP[0]語句，CMP比較語句以及JUMP E語句)。如果設(shè)置初始音頻數(shù)據(jù)(現(xiàn)在正在讀取的、BP[Offs]指向的環(huán)形緩沖)為全零，則可以省略這些檢查。與后面的幾千次采樣每次節(jié)省4周期相比，RAM初始化為全零的時(shí)間可忽略，新的循環(huán)代碼縮減至5個(gè)周期。

zeroes_filterloop:
    move  DP[1], DP[1]         ; 1, select DP[1] as our active pointer
    move  MA, @DP[1]++         ; 1, multiply next filter coefficient
    move  BP, BP               ; 1, select BP[Offs] as our active pointer
    move  MB, @BP[Offs--]      ; 1, multiply next filter data
    djnz  LC[0], zeroes_filterloop  ; 1

在回到性能方程之前，先查看一下結(jié)果計(jì)算。看起來當(dāng)前并不需要移位48位結(jié)果。

    move  A[2], MC2            ; get MAC result HIGH
    move  A[1], MC1            ; get MAC result MID
    move  A[0], MC0            ; get MAC result LOW
    move  APC, #0C2h           ; clear AP, roll modulo 4, auto-dec AP

shift_loop:
    ;
    ; Because we use fixed point precision, we need to shift to get a real
    ; sample value.  This is not as efficient as it could be.  If we had a
    ; dedicated filter, we might make use of the shift-by-2 and shift-by-4
    ; instructions available on MAXQ.
    ;
    move  AP, #2               ; select HIGH MAC result
    move  c, #0                ; clear carry
    rrc                        ; shift HIGH MAC result
    rrc                        ; shift MID MAC result
    rrc                        ; shift LOW MAC result
    djnz  LC[1], shift_loop    ; shift to get result in A[0]
    move APC, #0               ; restore accumulator normalcy
    move AP, #0                ; use accumulator 0

一個(gè)可能的方法是再次采用MAC。不采取右移12位(或0和16間的任一數(shù)值)，而是向左移16減去該值的位數(shù)(如左移4位)。這會使結(jié)果處于MAC寄存器16位字的中間。注意，左移的實(shí)際結(jié)果是乘以2的若干次冪(假如開始準(zhǔn)備右移12位時(shí)，為16)。

    ;
    ; don't care about high word, since we shift left and take the
    ; middle word.
    ;
    move  A[1], MC1            ; 1, get MAC result MID
    move  A[0], MC0            ; 1, get MAC result LOW
    move  MCNT, #20h           ; 1, clear the MAC, multiply mode only
    move  AP, #0               ; 1, use accumulator 0
    and   #0F000h              ; 2, only want the top 4 bits
    move  MA, A[0]             ; 1, lower word first
    move  MB, #10h             ; 1, multiply by 2^4
    move  A[0], MC1R           ; 1, get the high word, only lowest 4 bits significant
    move  MA, A[1]             ; 1, now the upper word, we want lowest 12 bits
    move  MB, #10h             ; 1, multiply by 2^4
    or    MC1R                 ; 1, combine the previous result and this one
    ;
    ; result is in A[0]
    ;

這將花費(fèi)12個(gè)周期進(jìn)行結(jié)果計(jì)算，而不是9 ＋ (6 x S)個(gè)周期。

現(xiàn)在回到前面的方程中。新方程保守估計(jì)開銷占用40個(gè)周期，每個(gè)循環(huán)迭代占5周期。采用與前面相同的100抽頭濾波器，MAXQ2000能夠處理16位、37kHz單聲道音頻數(shù)據(jù)，如表1所示。

表1. FIR濾波器最大采樣速率(20MHz MAXQ2000，循環(huán))

Filter Length (Taps)	Max Rate (Hz)
50	68965.51724
100	37037.03704
150	25316.4557
200	19230.76923
250	15503.87597
300	12987.01299
350	11173.18436

對于需要更高采樣率的應(yīng)用、可犧牲代碼空間進(jìn)一步提高性能?？梢浴皟?nèi)嵌”濾波器參數(shù)，不再需要選擇有效指針和循環(huán)(該技術(shù)也稱為循環(huán)展開)。這種改變的代價(jià)是增加代碼空間，以前需要100個(gè)字來存儲一個(gè)100個(gè)點(diǎn)的濾波器；現(xiàn)在，則需要300個(gè)字來存儲(每個(gè)參數(shù)移動為2個(gè)字，每個(gè)數(shù)據(jù)移動為1個(gè)字)。在16k字的器件中，相對于性能的提高，這種代價(jià)可忽略。新代碼形式如下：

    move  BP, BP               ; select BP[Offs] as our active pointer
zeroes_filtertop:
    move  MA, #FILTERCOEFF_0   ; 2, multiply next filter coefficient
    move  MB, @BP[Offs--]      ; 1, multiply next filter data
    move  MA, #FILTERCOEFF_1   ; 2, multiply next filter coefficient
    move  MB, @BP[Offs--]      ; 1, multiply next filter data
    move  MA, #FILTERCOEFF_2   ; 2, multiply next filter coefficient
    move  MB, @BP[Offs--]      ; 1, multiply next filter data
    . . .
    move  MA, #FILTERCOEFF_N   ; 2, multiply next filter coefficient
    move  MB, @BP[Offs--]      ; 1, multiply next filter data
    ;
    ; filter calculation complete
    ;

為計(jì)算這種改動的性能優(yōu)點(diǎn)，再次假設(shè)開銷為40周期，但是現(xiàn)在每循環(huán)迭代為3周期，但實(shí)際上消除了循環(huán)。這樣100抽頭濾波器最大可處理58kHz (參見表2)。

表2. FIR濾波器最大采樣速率(20MHz MAXQ2000，循環(huán)展開)

Filter Length (Taps)	Max Rate (Hz)
50	105263.1579
100	58823.52941
150	40816.32653
200	31250
250	25316.4557
300	31250
350	27027.02703

支持IIR濾波器

盡管本應(yīng)用筆記沒有演示IIR濾波器，但并不表明MAXQ2000不支持該濾波器。所需改動為：

• 使用一段專用RAM來存儲最后的輸出采樣(環(huán)形緩沖中使用該方法最有效，BP[Offs]寄存器的使用方式與前面描述的相似)
• 包括濾波器的反饋(‘y'部分)特征參數(shù)
• 加入另一個(gè)循環(huán)，該循環(huán)持續(xù)累加濾波器反饋部分的乘積結(jié)果

盡管加入另一個(gè)循環(huán)看起來會提高性能，但實(shí)際上可能并不需要。雖然需要更多的時(shí)間來計(jì)算濾波器的一個(gè)輸出，但I(xiàn)IR濾波器通常需要更少的抽頭(更小的N值)來計(jì)算輸出值。

結(jié)論

MAXQ2000具有的性能和外設(shè)可使其成為優(yōu)秀的通用微控制器，可以廣泛應(yīng)用在需要快速、通用微控制器(特別是需要用戶交互)的場合。高效的MAC使MAXQ2000具有一定的數(shù)字濾波能力，可成為最通用的通用微控制器。